(no subject)

[Alexandre Bonvin]

> i am working on simulation of a protien structure and am trying to get the
> trajectory files in the standard pdb format so that i can view them. so far
> what i have managed is a hexa output in 12Z6 format. i was wondering if
> anyone would know how to go about getting the output in the standard pdb
> format
>

You will need for that to write each record in the trajectory to a coordinate  
file. The script below will do the job. An alternative is to use vmd to  
directly view the X-PLOR trajectory (the trajectory must be in binary format).

> Obtaining VMD
> -------------
> A more complete description of VMD is available via the VMD WWW home page:
>         http://www.ks.uiuc.edu:1250/Research/vmd/
>
> The software itself is available via anonymous ftp in the directory:
>         ftp://ftp.ks.uiuc.edu/pub/mdscope/vmd
> (please see the README file in this directory for the latest version info)
>

Cheers,
Alexandre

==========================================================================
| Alexandre Bonvin PhD           | Phone: (203) 432-5066                 |
| Mol. Biophys. & Biochemistry   | Fax:   (203) 432-3923                 |
| Yale University                | Email: abonvin at laplace.csb.yale.edu   |
| New Haven CT 06520-8114, USA   | http://xplor.csb.yale.edu             |
==========================================================================



{====>}				{* filename and parameters *}

evaluate ($strucname = "il8.psf")
evaluate ($refname   = "il8.pdb")

evaluate ($trajname  = "traj/il8_random_sa.crd1")

{====>}				{* read structure and start coordinates *}
structure @$strucname end
coor disp=comp @@$refname

  evaluate ($tstart = 10 )
  evaluate ($tbegin = 10 )
  evaluate ($tstop  = 4000)
  evaluate ($tskip  = 10)
  evaluate ($tflag = 1 )

  while ( $tbegin <= $tstop ) loop ANALYS
	if ($tflag > 0 ) then
	  read traj
	    asci=true
	    inpu=$trajname
	    begi=$tbegin
	    skip=$tskip
	    stop=$tstop
	  end
	  eval ( $tflag = 0 )
	else
	  read traj next end
	end if
	coor fit sele = (name ca or name c or name n) end

        evaluate ($num = $tbegin)

	if ($num < 10) then
		evaluate ($filename = "traj/rsa000"+encode($num)+".pdb")
	elseif ($num < 100) then
		evaluate ($filename = "traj/rsa00"+encode($num)+".pdb")
	elseif ($num < 1000) then
		evaluate ($filename = "traj/rsa0"+encode($num)+".pdb")
	else
		evaluate ($filename = "traj/rsa"+encode($num)+".pdb")
	end if
	write coor output=$filename end
	close $filename end
 	eval ( $tbegin = $tbegin + $tskip )
  end loop ANALYS