NCS restraints

Gerard 'CD' Kleywegt GERARD at XRAY.BMC.UU.SE
Mon Jan 15 08:59:57 EST 1996

I've noticed the same thing for a protein where I could see an
extra residue at the N-terminus in one molecule, but not the other.
After some experimenting, I found out that both N-terminal
residues had to be omitted from the NCS statements (even though
one would expect that the second could be included if one also
excludes hydrogen atoms [since there are more Hs on the N-terminal
nitrogen]).  Something similar probably happens at differing
C-termini (or artificial termini where there are chain breaks)
due to the OT1/2 atoms.

So, if for one protein molecule you can model residue 1-100,
and for the other residue 3-96, you can probably only use
NCS restraints for the stretch 4-95.

I append an example "include file" for the protein mentioned
earlier (N-terminus at residue 85 for one, 86 for the other).
(Note that the weights are rather low, but this is at 1.8 A.)


---------------------------------------- 8< cut here ------------------

 { ncs_restraints.xplor }

 REMARK NCS-restraints for CBH II native at 1.8 A

 { use some identity arrays for the selection }

 { STORE1 = all non-hydrogen protein atoms }
 vector ident (store1) ((segid = "AAAA" or segid = "KKKK") and (not hydrogen)
                         and (not resid 85:86))

 { STORE2 = protein backbone }
 vector ident (store2) (store1 and ( name ca or name n or name c or name o
                        or name ot1 or name ot2 ))

 { STORE3 = side chains }
 vector ident (store3) (store1 and (not store2))

 { STORE4 = main chain with possible NCS-breakdown or disorder }
 vector ident (store4) (store2 and ( resi 86:88 or resi 96:98 or
                     resi 105:111 or resi 114:123 or resi 155:162 or
                     resi 288:290 or resid 309:311 or resi 405:412 or
                     resi 445:447 ))

 { STORE5 = side chains with possible NCS-breakdown or disorder }
 vector ident (store5) (store3 and (resi 86 or resi 89
   or resi 116:121 or resi 129 or resi 140:141 or resi 144 or resi 147 or resi 156:161
   or resi 182 or resi 186 or resi 189 or resi 194 or resi 204 or resi 208
   or resi 237 or resi 240 or resi 244 or resi 281 or resi 294 or resi 313
   or resi 319 or resi 344 or resi 356 or resi 362:363 or resi 382 or resi 406:411
   or resi 426 or resi 446:447) )

 ncs restraints

  { normal NCS protein backbone }
  group equi (segid "AAAA" and store2 and (not store4))
        equi (segid "KKKK" and store2 and (not store4))

  { non-NCS protein backbone }
  group equi (segid "AAAA" and store2 and store4)
        equi (segid "KKKK" and store2 and store4)

  { normal NCS protein sidechains }
  group equi (segid "AAAA" and store3 and (not store5))
        equi (segid "KKKK" and store3 and (not store5))

  { don't restrain sidechains with observed/likely NCS breakdown }



 { don't forget to include the ncs-restraint pseudo-energy term }

 flags include ncs ? end

More information about the X-plor mailing list