alternate conformations

[Jiansheng Jiang]

An example of Insulin which have second alternatives
both for sidechains of some residues in "A" chain and "B" chain.  

The two alternative sidechains are renamed as "A1" and "A2",
"B1" and "B2" respectively.

Jiansheng Jiang.

-------------------------------------------------------
remarks  file  xtalrefine/generate_alt.inp
remarks  rebuilt alternate conformations for sidechains

 parameter 


   @TOPPAR:parhcsdx.pro 

   @TOPPAR:york/paramow.wat

   nbonds                                       {* this statement specifies  *}
      atom cdie shift eps=1.0  e14fac=0.4       {* the nonbonded interaction *}
      cutnb=7.5 ctonnb=6.0 ctofnb=6.5           {* energy options.  Note the *}
      nbxmod=5 vswitch                          {* reduced nonbonding cutoff *}
   end                                          {* to save some CPU time     *}
 end


{===> read original "psf" and "pdb" files }

structure @genwat.psf   end            {*Read structure file.*}
coordinates @genwat.pdb                {*Read coordinates.*}



{=================================}
{ For sidechains of the "A" chain }
{=================================}

{===> select those have multiple comformations }
vector ident (store9)
       ( segid="A" and ( resid 14 or resid 15 ) and not 

         ( name ca or name n or name c or name o or name h ) ) 


{===> re-define them as "A1" }
vector do ( segid="A1" ) ( store9 )
vector do ( q=0.5 ) (store9 and name H*)

{===> generate the second alternative sidechains named as "A2" }
duplicate
    selection=( store9 ) 

    segid="A2"
end

{===> read coordinates for the second alternative "A2" }
coordinates @@a_alt2.pdb


{=================================}
{ For sidechains of the "B" chain }
{=================================}

{===> select those have multiple comformations }
vector ident (store8)
       ( segid="B" and ( resid 4 or resid 10 or resid 21 

                or resid 22 or resid 25 or resid 29 ) and not 

         ( name ca or name n or name c or name o or name h ) ) 


{===> re-define them as "B1" }
vector do ( segid="B1" ) ( store8 ) 

vector do ( q=0.5 ) (store8 and name H*)

{===> generate the second alternative sidechains named as "B2" }
duplicate
    selection=( store8 ) 

    segid="B2"
end

{===> read coordinates for the second alternative "B2" }
coordinates @@b_alt2.pdb


{===============================================}
{ Exclude interactions between two alternatives }
{ The following lines should also be included   }
{ in the subsequent input files for refinement  }
{===============================================}

{ NOTE: segid "E" contains other chains, i.e. waters and ions }

vector ident (store7) (segid "A" or segid "B" or segid "E")
vector ident (store6) (segid "A1" or segid "B1")
vector ident (store5) (segid "A2" or segid "B2")

constraints
   inter = (store7) (store7)
   inter = (store7 or store6) (store6)
   inter = (store7 or store5) (store5)
end


{===============================================}
{ Rebuild hydrogens for the second comformation }
{===============================================}

 flags exclude vdw elec end      {* do hydrogen building w/o vdw and elec   *}

 hbuild                          {* this statement builds missing hydrogens *}
    selection=( store5 and hydrogen )
    phistep=4
 end

{====================================}
{ write out new "psf" and "pdb" file }
{====================================}

write structure  output=generate_alt.psf end        {*Write structure file.*}
write coordinates output=generate_alt.pdb end      {*Write coordinate file.*} 

  

stop